eUpdate - canal eletrônico de informação e atualização sobre o mundo DataFlex

DICA TÉCNICA:
Inserindo animação em aplicações Windows

Quando copiamos um arquivo no Windows Explorer, é exibida uma animação mostrando o processo de cópia. O mesmo ocorre ao excluir um arquivo e também em muitas outras operações.

Estes recursos enchem os olhos dos usuários e, embora não sejam vitais para a operação realizada, tornam a utilização do software muito mais interessante para eles.

Utilizando a classe cAnimation, você também pode exibir animações no formato AVI em suas aplicações VDF Windows.

Um tipo de utilização comum para um controle de animação é indicar a atividade do sistema durante uma operação. O objeto da classe cAnimation usa uma thread separada e, por isso, a animação continuará “rodando” enquanto o processamento é executado.

Algumas observações importantes sobre o formato do arquivo AVI a ser usado:

• O controle cAnimation pode exibir uma animação de um arquivo AVI uncompressed ou compressed usando o run-length (BI_RLE8) enconding.
• O arquivo AVI não pode ter som.
• As capacidades do controle de animação são limitadas e estão sujeitas a mudanças pela Microsoft, por isso é recomendado que você teste o recurso em cada sistema operacional para o qual pretende portar sua aplicação.

Para começar a rodar um arquivo de animação você deve configurar a propriedade pbActive para true. Essa propriedade é usada para iniciar ou parar a animação. É importante saber que se você configurar essa propriedade como True e a animação não puder ser rodada, ela mudará automaticamente para False (que é o padrão).

Antes do arquivo ser iniciado, ele deve estar aberto. Há vários meios de fazer isso.

A forma mais simples é configurar a propriedade peAnimation com o nome de uma animação pré-definida do VDF, tal como aviFileCopy. Vários arquivos de animação são fornecidos e você pode acessá-los com essa propriedade. Por exemplo:

Set peAnimation to aviFileDelete
Set pbActive to True

Para usar outros arquivos AVI, use a propriedade psFileName. Configure-a com o nome de um arquivo de animação existente em disco. Por exemplo:

Set psFileName to "c:\Test.avi"
Set pbActive to True

Você também pode usar o método DoOpen para abrir um arquivo de animação. Dispare a procedure DoOpen com o nome de um arquivo de animação em disco. O método DoClose fecha o arquivo.

Send DoOpen "c:\Test.avi"
Set pbActive To True

Vejamos uma situação prática de uso:

Em um determinado botão, você vai executar uma exclusão de registros que pode demorar até 10 segundos. O código abaixo mostra como criar um objeto cAnimation que efetua o processamento e exibe a animação.

Object oDeleteFiles is a cAnimation
    Set Location to 37 106
    Set Size to 30 70
    Set pbTransparent to True // roda de forma “transparente”
    Set pbAutoSize to True // ajusta o controle do AVI
    Set piRepetitions to 0 // repete indefinidamente

    Procedure DoDeleteRows
        Set peAnimation to aviFileDelete
        // Utiliza o arquivo FileDel.avi.
        // É recomendado que você copie este arquivo para o
        // diretório Bitmaps da sua Workspace para a workspace

        Set pbActive to True // Executa a animação

        // Coloque aqui o processamento de exclusão
        // Sleep 5 // Remova o comentário desta linha se quiser fazer um
                // teste e não possui um processamento ‘real’

        Set pbActive to False // pára de rodar
        Set peAnimation to aviNone // fecha a animação
    End_Procedure

End_Object // oDeleteFiles

Object oDelete_bn is a Button
    Set Label to "Apagar registros"
    Set Size to 14 57
    Set Location to 109 113

    Procedure OnClick
        Forward Send OnClick
        Send DoDeleteRows of oDeleteFiles
    End_Procedure
End_Object // oDelete_bn

Nesse exemplo utilizamos a propriedade pbTransparent para rodar o clipe de animação com um fundo transparente, e a propriedade pbAutoSize para ajustar automaticamente o tamanho do controle ao tamanho da animação que será exibida.

A propriedade piRepetitions foi usada para controlar o número de repetições da animação. No nosso caso definindo como “0” para que o número de repetições seja indefinido, pois iremos parar a animação quando terminar o processamento.

O resultado é o seguinte:

(antes da execução)

(durante a execução)

Uma observação importante é que colocamos o fonte completo na matéria, apenas para facilitar o entendimento, mas você não precisará digitá-lo “manualmente”, pois a classe cAnimation está disponível na Controls Palette:

Há muitas outras propriedades, eventos e métodos na classe cApplication que podem ser usados de acordo com sua necessidade. Para mais informações, consulte a referência da classe cAnimation no Help do VDF (Reference Library -> Class Reference -> cAnimation).

• voltar ao menu